c# 多线程编程 入门篇

开始本应该是一篇洋洋洒洒的文字, 不过我还是提倡先做起来, 在尝试中去理解.

---

先试试这个:

---

procedure TForm1.Button1Click(Sender: TObject);
var
 i: Integer;
begin
 for i := 0 to 500000 do
 begin
  Canvas.TextOut(10, 10, IntToStr(i));
 end;
end;

上面程序运行时, 我们的窗体基本是 "死" 的, 可以在你在程序运行期间拖动窗体试试...

Delphi 为我们提供了一个简单的办法(Application.ProcessMessages)来解决这个问题:

---

procedure TForm1.Button1Click(Sender: TObject);
var
 i: Integer;
begin
 for i := 0 to 500000 do
 begin
  Canvas.TextOut(10, 10, IntToStr(i));
  Application.ProcessMessages;
 end;
end;

这个 Application.ProcessMessages; 一般用在比较费时的循环中, 它会检查并先处理消息队列中的其他消息.

但这算不上多线程, 譬如: 运行中你拖动窗体, 循环会暂停下来...

在使用多线程以前, 让我们先简单修改一下程序:

---

function MyFun: Integer;
var
 i: Integer;
begin
 for i := 0 to 500000 do
 begin
  Form1.Canvas.Lock;
  Form1.Canvas.TextOut(10, 10, IntToStr(i));
  Form1.Canvas.Unlock;
 end;
 Result := 0;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
 MyFun;
end;

细数上面程序的变化:
1、首先这还不是多线程的, 也会让窗体假 "死" 一会;
2、把执行代码写在了一个函数里, 但这个函数不属于 TForm1 的方法, 所以使用 Canvas 是必须冠以名称(Form1);
3、既然是个函数, (不管是否必要)都应该有返回值;
4、使用了 500001 次 Lock 和 Unlock.

Canvas.Lock 好比在说: Canvas(绘图表面)正忙着呢, 其他想用 Canvas 的等会;
Canvas.Unlock : 用完了, 解锁!

在 Canvas 中使用 Lock 和 Unlock 是个好习惯, 在不使用多线程的情况下这无所谓, 但保不准哪天程序会扩展为多线程的; 我们现在学习多线程, 当然应该用.

在 Delphi 中使用多线程有两种方法: 调用 API、使用 TThread 类; 使用 API 的代码更简单.

---

function MyFun(p: Pointer): Integer; stdcall;
var
 i: Integer;
begin
 for i := 0 to 500000 do
 begin
  Form1.Canvas.Lock;
  Form1.Canvas.TextOut(10, 10, IntToStr(i));
  Form1.Canvas.Unlock;
 end;
 Result := 0;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
 ID: THandle;
begin
 CreateThread(nil, 0, @MyFun, nil, 0, ID);
end;

代码分析:
CreateThread 一个线程后, 算上原来的主线程, 这样程序就有两个线程、是标准的多线程了;
CreateThread 第三个参数是函数指针, 新线程建立后将立即执行该函数, 函数执行完毕, 系统将销毁此线程从而结束多线程的故事.

CreateThread 要使用的函数是系统级别的, 不能是某个类(譬如: TForm1)的方法, 并且有严格的格式(参数、返回值)要求, 不管你暂时是不是需要都必须按格式来;
因为是系统级调用, 还要缀上 stdcall, stdcall 是协调参数顺序的, 虽然这里只有一个参数没有顺序可言, 但这是使用系统函数的惯例.

CreateThread 还需要一个 var 参数来接受新建线程的 ID, 尽管暂时没用, 但这也是格式; 其他参数以后再说吧.

这样一个最简单的多线程程序就出来了, 咱们再用 TThread 类实现一次

---

type
 TMyThread = class(TThread)
 protected
  procedure Execute; override;
 end;

procedure TMyThread.Execute;
var
 i: Integer;
begin
 FreeOnTerminate := True; {这可以让线程执行完毕后随即释放}
 for i := 0 to 500000 do
 begin
  Form1.Canvas.Lock;
  Form1.Canvas.TextOut(10, 10, IntToStr(i));
  Form1.Canvas.Unlock;
 end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
 TMyThread.Create(False);
end;

TThread 类有一个抽象方法(Execute), 因而是个抽象类, 抽象类只能继承使用, 上面是继承为 TMyThread.

继承 TThread 主要就是实现抽象方法 Execute(把我们的代码写在里面), 等我们的 TMyThread 实例化后, 首先就会执行 Execute 方法中的代码.

按常规我们一般这样去实例化:

procedure TForm1.Button1Click(Sender: TObject);
var
 MyThread: TMyThread;
begin
 MyThread := TMyThread.Create(False);
end;

因为 MyThread 变量在这里毫无用处(并且编译器还有提示), 所以不如直接写做 TMyThread.Create(False);

我们还可以轻松解决一个问题, 如果: TMyThread.Create(True) ?
这样线程建立后就不会立即调用 Execute, 可以在需要的时候再用 Resume 方法执行线程, 譬如:

---

procedure TForm1.Button1Click(Sender: TObject);
var
 MyThread: TMyThread;
begin
 MyThread := TMyThread.Create(True);
 MyThread.Resume;
end;

//可简化为:
procedure TForm1.Button1Click(Sender: TObject);
begin
 with TMyThread.Create(True) do Resume;
end;

使用 TThread 类时, Delphi 有提供的模板, 但用 IDE 写代码很方便, 我重写一遍录下来给大家看:



期间使用了 Ctrl+J、Shift+Ctrl+C、Ctrl+Alt+P 等快捷键.

---

重要的修正与补充:

---

在 TThread 类的例子中, 应该有这句: FreeOnTerminate := True; (原来漏掉, 代码中已加上; 但动画加不上了).

先说它什么意思:
类 Create 了就要 Free;
但 TThread(的子类) 有特殊性, 很多时候我们不能确定新建的线程什么时候执行完(也就是什么时候该释放);
如果线程执行完毕自己知道释放就好了, 所以 TThread 给了一个布尔属性 FreeOnTerminate, 如果为 True, 线程执行完毕后就会自释放.

我怎么会忽略了这么重要的问题呢? 原因有二:
1、我一直在追求最精炼的代码;
2、我手头上不只一本书上介绍说: FreeOnTerminate 的默认值是 True(错误!), 经落实, 应该是 False, 起码在 Delphi 2007 和 2009 中是这样; 或许以前的某个版本和现在不一样.